WIDTH = 25.0 # Width/cm of the graph
HEIGHT = 14.0 # Height/cm of the graph

XMIN = 0.4 # Minimum value for the x axis
XMAX = 3.2 # Maximum value for the x axis

# If YMIN = YMAX, default values are used
YMIN = 0 # Minimum value for the y axis
YMAX = 0 # Maximum value for the y axis

# If Y2MIN = Y2MAX, default values are used
Y2MIN = 0 # Minimum value for the y axis
Y2MAX = 0 # Maximum value for the y axis

IVSIZE = 15 # Size (integer) of numerical values for the x and y axes
ILSIZE = 17 # Size (integer) of labels for the x and y axes

 SYLBL = -1.5 # Shift of the  y label along the x axis in the unit of a character
SY2LBL =  1.2 # Shift of the y2 label along the x axis in the unit of a character

DLW = 1 # Default linewidth
BLW = 1 # Linewidth of graph borders

set terminal pdfcairo linewidth DLW size WIDTH/2.54, HEIGHT/2.54 fontscale 0.75
set border linewidth BLW
set tics scale 1.7, 0.9

# An element symbol is substituted for '@@' by xdc.bat (Windows) or xdc.command (OS X)
set title "X-Ray dispersion and absorption for @@" offset 0, 0 font ",".ILSIZE

set xtics nomirror offset -0.2, 0.17 autofreq font ",".IVSIZE
set mxtics 5 # The number of sub-intervals between major tics
set encoding iso_8859_1 # To write Angstrom: \305
set xlabel "{/:Italic \316\273}&{/=14 |}/&{/=7 |}\303\205" offset 0, -0.1 font ",".ILSIZE

set x2tics nomirror offset -0.3, 0.23 ( 4, 5, 6, 7, 8, 9, 10, 15, 20, 25, "" 30 ) font ",".IVSIZE # Major tics
set x2tics add ( 4.2 1, 4.4 1, 4.6 1, 4.8 1, 5.2 1, 5.4 1, 5.6 1, 5.8 1, 6.2 1, 6.4 1, 6.6 1, 6.8 1, \
7.2 1, 7.4 1, 7.6 1, 7.8 1, 8.2 1, 8.4 1, 8.6 1, 8.8 1, 9.2 1, 9.4 1, 9.6 1, 9.8 1, 11 1, 12 1, 13 1, \
14 1, 16 1, 17 1, 18 1, 19 1, 21 1, 22 1, 23 1, 24 1, 26 1, 27 1, 28 1, 29 1 ) # Minor tics
set link x2 via 12.3984/x inverse 12.3984/x
set x2label "{/:Italic E}&{/=12 |}/&{/=11 |}keV" offset 0, 0.4 font ",".ILSIZE

#set minussign

set ytics nomirror offset 0.2, 0.22 autofreq font ",".IVSIZE
set mytics default # The number of sub-intervals between major tics
set ylabel "Dispersion correction" offset SYLBL, 0 font ",".ILSIZE

set y2tics nomirror offset -0.8, 0.22 autofreq font ",".IVSIZE

set my2tics default # The number of sub-intervals between major tics
set y2label "{/:Italic \316\274}_m&{/=12 |}/&{/=10 |}cm^{2}&{/=20 |}g^{\342\200\2231}" offset SY2LBL, 0 font ",".ILSIZE

# set key {left | right | center} {top | bottom | center}
set key right bottom spacing 3.2 height 1

set xrange [XMIN:XMAX]
if (YMIN == YMAX) {
  set yrange [:] # Autoscaling of the y axis
} else {
  set yrange [YMIN:YMAX] # Range of dispersion corrections (y axis)
}
if (Y2MIN == Y2MAX) {
  set y2range [:] # Autoscaling of the y2 axis
} else {
  set y2range [Y2MIN:Y2MAX] # Range of mass attenuation coeffcients (y2 axis)
}
# Margins measured in character widths or heights (a negative value: automatic)
set margins -1, -1, 4.5, 7 # <left>, <right>, <bottom>, <top>

plot 'element.dat' \
   every :::0::0 using 1:3 title "{/:Italic=16 f}&{/=8 |}{/=16 \342\200\262}" with lines linetype 11 linecolor rgbcolor "red", \
'' every :::0::0 using 1:4 title "{/:Italic=16 f}&{/=8 |}{/=16 \342\200\263}" with lines linetype 11 linecolor rgbcolor "blue", \
'' every :::1::1 using (0.0123984/$1):2 title "{/:Italic=15 \316\274}_{/=13 m}" axes x1y2 with lines linetype 11 linecolor rgbcolor "forest-green"