#===============================================
# TkEllipsometryFCA
#===============================================
package TkEllipsometryFCA;
use clib::TkEllipsometry;
@ISA = qw(TkEllipsometry);

#公開したいサブルーチン
#@EXPORT = qw(DelSpace Reduce01 MakePath RegExpQuote);

use strict;

my $pi    = Sci::pi();
my $kB    = Sci::kB();
my $c     = Sci::c();
my $e     = Sci::e();
my $e0    = Sci::e0();
my $me    = Sci::me();
my $mp    = Sci::mp();
my $mn    = Sci::mn();
my $h     = Sci::h();
my $hbar  = Sci::hbar();
my $torad = Sci::torad();
my $todeg = Sci::todeg();

#============================================================
#　変数等取得関数
#============================================================

#============================================================
#　コンストラクタ、デストラクタ
#============================================================

#============================================================
#　継承クラスで定義しなおす関数
#============================================================
sub CreateWidgets
{
	my ($this) = @_;
	my $App    = $this->App();
	my $args   = $App->Args();
	my $mw     = $this->mw();

	$this->{ini}  = new IniFile(undef, 0, 0);
	$this->{dini} = new IniFile(undef, 0, 0);
	$this->{Ellipsometry} = new Ellipsometry;

	$this->SUPER::CreateWidgets(1);
	$mw->SetTitle("Ellipsometry for FCA 2007 / TkPlot");
	$this->App()->SetProgram("Ellipsometry for FCA 2007 / TkPlot");

	$this->{nLorentz} = 2 if(!defined $this->{nLorentz});
	$this->{nDrude}   = 1 if(!defined $this->{nDrude});

#===================================================
# ペインを作製
#===================================================
	my $EntryWidth =  12;

	my $Frame = $mw->MyFrame()->pack(-anchor => 'nw', -fill => 'x');
	$this->MakeChooseFileEntry($Frame, 'Param', 'Param:', $this->{ini}->pVariable("ParameterFile", ""), 
				'&Choose', sub { $this->ChooseFile(@_); }, "ChooseParameterFile");
	$this->{SaveParamButton} = $Frame->MyButton(
			-text => '&Save',
			-takefocus => 1,
			-command => sub { $this->ButtonPressed('RButtonDown', 'SaveParam'); },
		)->pack(-side => 'left');
	$this->{EditParamButton} = $Frame->MyButton(
			-text => 'ed',
			-takefocus => 1,
			-command => sub { $this->ButtonPressed('RButtonDown', 'EditParam'); },
		)->pack(-side => 'left');

	$Frame = $mw->MyFrame()->pack(-anchor => 'nw', -fill => 'x');
	$this->MakeChooseFileEntry($Frame, 'SampleCSV', 'Sample:', $this->{ini}->pVariable("SampleCSVFile", ""), 
				'&Choose', sub { $this->ChooseFile(@_); }, "ChooseSampleFile");
	$this->{EditDataButton} = $Frame->MyButton(
			-text => 'ed',
			-takefocus => 1,
			-command => sub { $this->ButtonPressed('RButtonDown', 'EditSampleCSV'); },
		)->pack(-side => 'left');

	$Frame = $mw->MyFrame()->pack(-anchor => 'nw', -fill => 'x');
	$this->MakeChooseFileEntry($Frame, 'SubstrateCSV', 'Substrate:', $this->{ini}->pVariable("SubstrateCSVFile", ""),
				'&Choose', sub { $this->ChooseFile(@_); }, "ChooseSubstrateFile");
	$this->{EditDataButton} = $Frame->MyButton(
			-text => 'ed',
			-takefocus => 1,
			-command => [\&ButtonPressed, $this, 'RButtonDown', 'EditSubstrateCSV'],
		)->pack(-side => 'left');

	$Frame = $mw->MyFrame()->pack(-anchor => 'nw', -fill => 'x');
	my $lsb1 = $this->{ChooseXListBox} = $Frame->MyBrowseEntry(
			-label      => "X:",
			-state      => "readonly",
			-takefocus  => 1,
			-width      => 5,
			-Selections => [],
			-SelIndex   => 0,
		)->pack(-side => 'left', -expand => 'yes', -fill => 'x');
	$lsb1->configure(-browsecmd  => [ \&SelChangeListBox, $this, "X", $this->{ChooseXListBox} ] );
	my $lsb2 = $this->{ChooseY1ListBox} = $Frame->MyBrowseEntry(
			-label      => "Y1:",
			-state      => "readonly",
			-takefocus  => 1,
			-width      => 5,
			-Selections => [],
			-SelIndex   => 1,
		)->pack(-side => 'left', -expand => 'yes', -fill => 'x');
	$lsb2->configure(-browsecmd  => [ \&SelChangeListBox, $this, "Y1", $this->{ChooseY1ListBox} ]);
	my $lsb3 = $this->{ChooseY2ListBox} = $Frame->MyBrowseEntry(
			-label      => "Y2:",
			-state      => "readonly",
			-takefocus  => 1,
			-width      => 5,
			-Selections => [],
			-SelIndex   => 2,
		)->pack(-side => 'left', -expand => 'yes', -fill => 'x');
	$lsb3->configure(-browsecmd  => [ \&SelChangeListBox, $this, "Y2", $this->{ChooseY2ListBox} ]);

	$Frame = $mw->MyLabFrame(
			-label     => 'Fitting1',
			-labelside => 'acrosstop',
			)->pack(-anchor => 'nw', -fill => 'x');
	my $lsb4 = $this->{ChooseLSQMethodListBox} = $Frame->MyBrowseEntry(
			-label      => "LSQ Method:",
			-state      => "readonly",
			-takefocus  => 1,
			-width      => 5,
			-Selections => ['Amoeba::Simplex', 'PDL::Simplex', 'ModifiedNewton'],
			-SelIndex   => 0,
		)->pack(-side => 'left', -expand => 'yes', -fill => 'x');
	$lsb4->configure(-browsecmd  => [\&SelChangeListBox, $this, "LSQMethod", $this->{ChooseLSQMethodListBox}]);
	my $lsb5 = $this->{ChooseFitToListBox} = $Frame->MyBrowseEntry(
			-label      => "Fit to:",
			-state      => "readonly",
			-takefocus  => 1,
			-width      => 5,
			-Selections => ['Eps', 'PsiDelta', 'IsIcII', 'IsIcIII'],
			-SelIndex   => 0,
		)->pack(-side => 'left', -expand => 'yes', -fill => 'x');

	$Frame = $mw->MyLabFrame(
			-label     => 'Fitting2',
			-labelside => 'acrosstop',
			)->pack(-anchor => 'nw');
	$this->MakeLabelEntry($Frame, "FitEmin", "Emin:", 
			$this->{ini}->pVariable('FitEmin', ''), "%s", $EntryWidth, "eV", 0, 0);
	$this->MakeLabelEntry($Frame, "FitEmax", "Emax:", 
			$this->{ini}->pVariable('FitEmax', ''), "%s", $EntryWidth, "eV", 0, 1);
	$this->MakeLabelEntry($Frame, "nSkipData", "nSkip:", 
			$this->{ini}->pVariable('nSkipData', 2), "%d", $EntryWidth, "", 0, 2);
	$this->MakeLabelEntry($Frame, "EPS", "EPS:", 
			$this->{ini}->pVariable('EPS', 1.0e-5), "%12.4g", $EntryWidth, "", 1, 0);
	$this->MakeLabelEntry($Frame, "nMaxIter", "MaxIter:", 
			$this->{ini}->pVariable('nMaxIter', 1000), "%d", $EntryWidth, "", 1, 1);
	$this->MakeLabelEntry($Frame, "nSaveSpectraInterval", "SaveIntvl:", 
			$this->{ini}->pVariable('nSaveSpectraInterval', 10), "%d", $EntryWidth, "", 1, 2);

	$Frame = $mw->MyLabFrame(
			-label     => 'Ellipsometry',
			-labelside => 'acrosstop',
			)->pack(-anchor => 'nw');
	$this->MakeLabelEntry($Frame, "Angle", "Angle:", 
			$this->{ini}->pVariable('Angle', 70.0), "%8.4f", $EntryWidth, "deg", 0, 0);

	$Frame = $mw->MyLabFrame(
			-label     => 'Film',
			-labelside => 'acrosstop',
			)->pack(-anchor => 'nw');
	$this->MakeCheckEntry($Frame, "FilmThickness", "Thickness:", $this->{dini}->pVariable('FilmThicknesscheck', 1),
			$this->{ini}->pVariable('FilmThickness', 100.0), "%12.6g", $EntryWidth, "nm", 0, 0);
	my $lsb6 = $this->{ChooseLayerModelBox} = $Frame->MyBrowseEntry(
			-label      => "Layer Model:",
			-state      => "readonly",
			-takefocus  => 1,
			-width      => 10,
			-Selections => ["Film/Substrate"],
			-SelIndex   => 0,
		)->grid(-row => 0, -column => 3, -columnspan => 1, -sticky => 'e' );
	$lsb6->configure(-browsecmd  => [\&SelChangeListBox, $this, "LayerModel", $this->{ChooseLayerModelListBox}]);

	$Frame = $mw->MyLabFrame(
			-label     => 'Dielectric background',
			-labelside => 'acrosstop',
			)->pack(-anchor => 'nw');
	$this->MakeCheckEntry($Frame, "e1inf", "e1:", $this->{dini}->pVariable('e1infcheck', 1) ,
			$this->{ini}->pVariable('e1inf', 0.155), "%12.6g", $EntryWidth, "e0", 0, 0);
	$this->MakeCheckEntry($Frame, "e2inf", "e2:", $this->{dini}->pVariable('e2infcheck', 0) ,
			$this->{ini}->pVariable('e2inf', 0.0  ), "%12.6g", $EntryWidth, "e0", 0, 1);

	$Frame = $mw->MyLabFrame(
			-label     => 'Tauc-Lorentz',
			-labelside => 'acrosstop',
			)->pack(-anchor => 'nw');
	$this->MakeCheckEntry($Frame, "A", "A:", $this->{dini}->pVariable('Acheck', 1) ,
			$this->{ini}->pVariable('A', 122.8), "%12.6g", $EntryWidth, "", 0, 0);
	$this->MakeCheckEntry($Frame, "C", "C:", $this->{dini}->pVariable('Ccheck', 1) ,
			$this->{ini}->pVariable('C', 10.8), "%12.6g", $EntryWidth, "", 0, 1);
	$this->MakeCheckEntry($Frame, "Eg", "Eg:", $this->{dini}->pVariable('Egcheck', 1) ,
			$this->{ini}->pVariable('Eg', 4.4), "%12.6g", $EntryWidth, "eV", 1, 0);
	$this->MakeCheckEntry($Frame, "En0", "En0:", $this->{dini}->pVariable('En0check', 1) ,
			$this->{ini}->pVariable('En0', 155.9), "%12.6g", $EntryWidth, "eV", 1, 1);

	$Frame = $mw->MyLabFrame(
			-label     => "Lorentz",
			-labelside => 'acrosstop',
			)->pack(-anchor => 'nw');
	for(my $i = 0 ; $i < $this->{nLorentz} ; $i++) {
		my $i1 = $i + 1;
		$this->MakeCheckEntry($Frame, "E0${i1}", "E0:", $this->{dini}->pVariable("E0${i1}check", 1) ,
				$this->{ini}->pVariable("E0${i1}", 2.64), "%12.6g", $EntryWidth, "eV", $i, 0);
		$this->MakeCheckEntry($Frame, "Ne${i1}", "Ne:", $this->{dini}->pVariable("Ne${i1}check", 1) ,
				$this->{ini}->pVariable("Ne${i1}", 2e26), "%12.6g", $EntryWidth, "m-3", $i, 1);
		$this->MakeCheckEntry($Frame, "G${i1}", "G:", $this->{dini}->pVariable("G${i1}check", 1) ,
				$this->{ini}->pVariable("G${i1}", 2.64),   "%12.6g", $EntryWidth, "eV", $i, 2);
	}

	$Frame = $mw->MyLabFrame(
			-label     => "Drude",
			-labelside => 'acrosstop',
			)->pack(-anchor => 'nw');
	for(my $i = 0 ; $i < $this->{nDrude} ; $i++) {
		my $i1 = $i + 1;
		$this->MakeCheckEntry($Frame, "DrudeEp${i1}", "Ep:", $this->{dini}->pVariable("DrudeEp${i1}check", 1) ,
				$this->{ini}->pVariable("DrudeEp${i1}", 0.0),      "%12.6g", $EntryWidth, "eV", $i, 1);
		$this->MakeCheckEntry($Frame, "Drudetau${i1}", "tau:", $this->{dini}->pVariable("Drudetau${i1}check", 1) ,
				$this->{ini}->pVariable("Drudetau${i1}", 1.0e-14), "%12.6g", $EntryWidth, "s", $i, 2);
	}

	$this->UpdateParameters();

	$Frame = $mw->MyFrame()->pack(-anchor => 'nw', -fill => 'x');
	$this->{RecalcButton} = $Frame->MyButton(
			-text => 'Re&calc',
			-takefocus => 1,
			-command => sub { $this->ButtonPressed('RButtonDown', 'Recalc'); },
		)->pack(-side => 'left');
	$this->{FitButton} = $Frame->MyButton(
			-text => '&Fit',
			-takefocus => 1,
			-command => sub { $this->ButtonPressed('RButtonDown', 'Fit'); },
		)->pack(-side => 'left');
	$this->{SaveForSCOUTButton} = $Frame->MyButton(
			-text => 'Save for &SCOUT',
			-takefocus => 1,
			-command => sub { $this->ButtonPressed('RButtonDown', 'SaveForSCOUT'); },
		)->pack(-side => 'left');

#ツールバーのOpenボタンをファイル読み込みにバインドする
	$mw->{OpenButton}->configure(
			-command  => sub { $this->ChooseFile('SampleCSVFile', $this->{SPEFileFileEntry}); },
		) if($mw->{OpenButton});
}

sub SelChangeListBox
{
	my ($this, $type, $lb) = @_;
#print "this:$this  lb=$lb\n";
	my $s = $lb->GetText();
	$this->AssignGraphData();
	$this->Draw();
}

sub ChooseFile
{
	my ($this, $type, $widget, $Option) = @_;
	my $App = $this->App();
	my $canvas = $this->Canvas();
	my $mw = $this->mw();

#print "Opt=$Option\n";
	my $mode = 'open';
	my $fmask = '*.csv;*.spe;*.jel;*.asp;*.smo;*isa;*.ref;*.pal;*.bef;*.aft';
	if($Option eq 'ChooseParameterFile') {
#		$mode = 'save';
		$fmask = '*.prm';
	}

	my $dir = '';
	unless($widget) {
		$dir = $this->App()->{WorkDir};
		chdir($dir);
	}
	my $defstr = '';
	my $message = 'Choose file';
	my $filepath = Dialog::OpenFileDialog($mw, 
				'open', $fmask, $defstr, $message, $dir);
	if($filepath) {
		my $DirPath = $this->SetWorkDir($filepath);
		if($widget) {
			$widget->SetText($filepath);
		}
	}
	else {
		return undef;
	}

	my $ret;
	if($Option eq 'ChooseParameterFile') {
		$ret = $this->ReadParameterFile($filepath);
		return undef unless($ret);
		$this->Draw();
	}
	elsif($Option eq 'ChooseSampleFile') {
		$ret = $this->ReadSampleDataFile($filepath);
		return undef unless($ret);
		$this->Draw();
	}

	return $ret;
}

sub ButtonPressed
{
	my ($this, $event, $type) = @_;
	my $App = $this->App();

	if($type eq 'Recalc') {
		$this->Recalc();
		$this->CreateGraphFrame();
		$this->AssignGraphData(1);
		$this->Draw();
	}
	elsif($type eq 'SaveForSCOUT') {
		$this->SaveForSCOUT();
	}
	elsif($type eq 'Fit') {
		&Fit($this);
		$this->Recalc();
#		$this->CreateGraphFrame();
		$this->AssignGraphData(0);
		$this->Draw();
		return;
	}
	elsif($type eq 'SaveParam') {
		$this->SaveParameterFile($this->{ini}->{ParameterFile});
		return;
	}
	elsif($type eq 'EditParam') {
		my $Editor  = $this->App()->{EditorPath};
		my $File = $this->{ini}->{ParameterFile};
		my $command = "$Editor $File";
		system($command);
		return;
	}
	elsif($type eq 'EditSampleCSV') {
		my $Editor  = $this->App()->{EditorPath};
		my $File = $this->{ini}->{SampleCSVFile};
		my $command = "$Editor $File";
		system($command);
		return;
	}
	elsif($type eq 'EditSubstrateCSV') {
		my $Editor  = $this->App()->{EditorPath};
		my $File = $this->{ini}->{SubstrateCSVFile};
		my $command = "$Editor $File";
		system($command);
		return;
	}
}

sub EntryFocusedIn {
	my ($this, $obj, $event, $type) = @_;
#print "In: obj=$obj, this=$this, event=$event, type=$type\n";

	if($event eq 'FocusIn') {
		$obj->{PrevValue} = $obj->GetText();
	}
}


sub EntryFocusedOut {
	my ($this, $obj, $event, $type) = @_;
#print "Out: obj=$obj, this=$this, event=$event, type=$type\n";
	my $ini  = $this->{ini};
	my $dini = $this->{dini};

	if($event eq 'FocusOut') {
	}
	if($ini->{AutoUpdate} and defined $dini->{"${type}check"} and $obj->{PrevValue} != $obj->GetText()) {
		$this->Recalc();
#		$this->CreateGraphFrame();
		$this->AssignGraphData(0);
		$this->Draw();
	}
	else {
		$this->UpdateParameters();
	}
}

#===================================================
# データ処理
#===================================================
sub BuildLayerModel
{
	my ($this, $IsPrint, $BuildOptimize) = @_;
	$IsPrint = 1 if(!defined $IsPrint);
	$BuildOptimize = 1 if(!defined $BuildOptimize);

	my $ini    = $this->{ini};
	my $dini   = $this->{dini};
	my $el     = $this->{Ellipsometry};

	my $optics = new Optics;
	my $Layers = new MultiLayer;
	$Layers->SetIncidentAngle($ini->{Angle});

	my $pObsE     = $el->GetData('.*eV.*', '.*E.*');
	my $pObsPsi   = $el->GetData('Psi');
	my $pObsDelta = $el->GetData('Delta');
	my $pObsEps1  = $el->GetData('e1');
	my $pObsEps2  = $el->GetData('e2');
	my $nData     = @$pObsE;
	my $nE        = $nData;
	$ini->{FitEmin} = $pObsE->[0]        if($ini->{FitEmin} eq '');
	$ini->{FitEmax} = $pObsE->[$nData-1] if($ini->{FitEmax} eq '');
	my $Emin  = $ini->{FitEmin};
	my $Emax  = $ini->{FitEmax};
	my $Estep = $pObsE->[1] - $pObsE->[0];

$Estep = 0.05 if(!defined $Estep);
$nData = int( ($Emax - $Emin) / $Estep + 1.001);

	my $Air       = new OpticalMaterial("air");
	my $Film      = new OpticalMaterial("Specify", "Film");
	my $Substrate = new OpticalMaterial("Specify", "Substrate");
	if($ini->{SubstrateCSVFile}) {
		my @ret = $Substrate->AddDielectricModel(
			"Substrate",
			"EFile",
			"Path", $ini->{SubstrateCSVFile},
			);
		if(@ret == 0) {
			print "Error: Can not read [$ini->{SubstrateCSVFile}].\n";
			return;
		}
	}

	$Film->AddDielectricModel(
		"Constant1",
		"Constant",
		"e1inf", $ini->{e1inf},
		"e2inf", $ini->{e2inf},
		);
	$Film->AddDielectricModel(
		"TaucLorentz1",
		"TaucLorentz",
		"A",     $ini->{A},
		"Eg",    $ini->{Eg},
		"En0",   $ini->{En0},
		"C",     $ini->{C}
		);
	for(my $i = 0 ; $i < $this->{nLorentz} ; $i++) {
		my $i1 = $i + 1;
		$Film->AddDielectricModel(
			"Lorentz$i1",
			"Lorentz",
			"Ne", $ini->{"Ne$i1"},
			"E0", $ini->{"E0$i1"},
			"G",  $ini->{"G$i1"},
			);
	}
	for(my $i = 0 ; $i < $this->{nDrude} ; $i++) {
		my $i1 = $i + 1;
		$Film->AddDielectricModel(
			"Drude$i1",
			"Drude",
			"Ep",  $ini->{"DrudeEp$i1"},
			"tau", $ini->{"Drudetau$i1"},
			);
	}

	$Layers->AddLayer($Air,       -1.0,                         0.0);
	$Layers->AddLayer($Film,      $ini->{FilmThickness}*1.0e-9, 1.0);
	$Layers->AddLayer($Substrate, -1.0,                         0.0);

	$this->{Layers} = $Layers;

	$Layers->PrintLayers() if($IsPrint);

#=========================================================
# フィッティング設定
#=========================================================
	return if(!$BuildOptimize);
	my $optimize = new Optimize();
	$optimize->AddParameters(
		"FilmThickness",  $Layers->pLayerThickness(1),
							$dini->{FilmThicknesscheck}, $dini->{FilmThicknessscale}, $dini->{FilmThicknessmin}, $dini->{FilmThicknessmax},
							sub {
								$Layers->SetLayerThickness(1, $_[0]);
								$ini->{FilmThickness} = $_[0]*1.0e9;
							},

		"e1",      $Layers->pVariable(1, 'Constant1::e1inf'),
							$dini->{e1infcheck}, $dini->{e1infscale}, $dini->{e1infmin}, $dini->{e1infmax},
							sub {
								$Layers->SetVariable(1, 'Constant1::e1inf', $_[0]); 
								$ini->{e1inf} = $_[0];
							},

		"e2",      $Layers->pVariable(1, 'Constant1::e2inf'),
							$dini->{e2infcheck}, $dini->{e2infscale}, $dini->{e2infmin}, $dini->{e2infmax},
							sub {
								$Layers->SetVariable(1, 'Constant1::e2inf', $_[0]); 
								$ini->{e2inf} = $_[0];
							},

		"TLA",     $Layers->pVariable(1, 'TaucLorentz1::A'),
							$dini->{Acheck}, $dini->{Ascale}, $dini->{Amin}, $dini->{Amax},
							sub {
								$Layers->SetVariable(1, 'TaucLorentz1::A', $_[0]); 
								$ini->{A} = $_[0];
							},

		"TLC",     $Layers->pVariable(1, 'TaucLorentz1::C'),
							$dini->{Ccheck}, $dini->{Cscale}, $dini->{Cmin}, $dini->{Cmax},
							sub {
								$Layers->SetVariable(1, 'TaucLorentz1::C', $_[0]); 
								$ini->{C} = $_[0];
							},

		"TLEg",    $Layers->pVariable(1, 'TaucLorentz1::Eg'),
							$dini->{Egcheck}, $dini->{Egscale}, $dini->{Egmin}, $dini->{Egmax},
							sub {
								$Layers->SetVariable(1, 'TaucLorentz1::Eg', $_[0]); 
								$ini->{Eg} = $_[0];
							},

		"TLEn0",   $Layers->pVariable(1, 'TaucLorentz1::En0'),
							$dini->{En0check}, $dini->{En0scale}, $dini->{En0min}, $dini->{En0max},
							sub {
								$Layers->SetVariable(1, 'TaucLorentz1::En0', $_[0]); 
								$ini->{En0} = $_[0];
							},
		);
	for(my $i = 0 ; $i < $this->{nLorentz} ; $i++) {
		my $i1 = $i + 1;
		$optimize->AddParameters(
			"L${i1}E0",    $Layers->pVariable(1, "Lorentz${i1}::E0"),
							$dini->{"E0${i1}check"}, $dini->{"E0${i1}scale"}, $dini->{"E0${i1}min"}, $dini->{"E0${i1}max"},
							sub {
								$Layers->SetVariable(1, "Lorentz${i1}::E0", $_[0]); 
								$ini->{"E0${i1}"} = $_[0];
							},

			"L${i1}Ne",    $Layers->pVariable(1, "Lorentz${i1}::Ne"),
							$dini->{"Ne${i1}check"}, $dini->{"Ne${i1}scale"}, $dini->{"Ne${i1}min"}, $dini->{"Ne${i1}max"},
							sub {
								$Layers->SetVariable(1, "Lorentz${i1}::Ne", $_[0]); 
								$ini->{"Ne${i1}"} = $_[0]; 
								$ini->{"A${i1}"} = $optics->CalLorentzAfromNe($ini->{"Ne${i1}"}, 1.0);
							},

			"L${i1}G",     $Layers->pVariable(1, "Lorentz${i1}::G"),
							$dini->{"G${i1}check"}, $dini->{"G${i1}scale"}, $dini->{"G${i1}min"}, $dini->{"G${i1}max"},
							sub {
								$Layers->SetVariable(1, "Lorentz${i1}::G", $_[0]); 
								$ini->{"G${i1}"} = $_[0];
							},

			);
	}
	for(my $i = 0 ; $i < $this->{nDrude} ; $i++) {
		my $i1 = $i + 1;
		$optimize->AddParameters(
			"D${i1}Ep",    $Layers->pVariable(1, "Drude${i1}::Ep"),
							$dini->{"DrudeEp${i1}check"}, $dini->{"DrudeEp${i1}scale"}, $dini->{"DrudeEp${i1}min"}, $dini->{"DrudeEp${i1}max"},
							sub {
								$Layers->SetVariable(1, "Drude${i1}::Ep", $_[0]); 
								$ini->{"DrudeEp${i1}"} = $_[0];
							},

			"D${i1}tau",    $Layers->pVariable(1, "Drude${i1}::tau"),
							$dini->{"Drudetau${i1}check"}, $dini->{"Drudetau${i1}scale"}, $dini->{"Drudetau${i1}min"}, $dini->{"Drudetau${i1}max"},
							sub {
								$Layers->SetVariable(1, "Drude${i1}::tau", $_[0]); 
								$ini->{"Drudetau${i1}"} = $_[0]; 
							},
			);
	}
	$this->{Optimize} = $optimize;
}

sub Recalc
{
	my ($this) = @_;

	$this->UpdateParameters();
	$this->BuildLayerModel(1, 0);

	my $el     = $this->{Ellipsometry};
	my $Layers = $this->{Layers};

	my $pObsE     = $el->GetData('.*eV.*', '.*E.*');
	my $pObsPsi   = $el->GetData('Psi');
	my $pObsDelta = $el->GetData('Delta');
	my $pObsEps1  = $el->GetData('e1');
	my $pObsEps2  = $el->GetData('e2');
	my $FitTo     = $this->{ChooseFitToListBox}->GetText();

	my ($pE, $pe1, $pe2, $pPsi, $pDelta, $pIs, $pIc, $S2)
			= $this->CalEpsPsiDelta($Layers, $pObsE, $pObsPsi, $pObsDelta, $pObsEps1, $pObsEps2, $FitTo);
	$this->{pEArray}     = $pE;
	$this->{pe1Array}    = $pe1;
	$this->{pe2Array}    = $pe2;
	$this->{pPsiArray}   = $pPsi;
	$this->{pDeltaArray} = $pDelta;
	$this->{pIsArray}    = $pIs;
	$this->{pIcArray}    = $pIc;

	$this->App()->print("Recalc: S2=$S2\n");
	$this->SetS2($S2);

	return $S2;
}

sub Fit
{
	my ($this) = @_;
	my $ini      = $this->{ini};
	my $dini     = $this->{dini};
	$this->UpdateParameters();
	$this->BuildLayerModel(0, 1);

	my $optimize = $this->{Optimize};
	my $Method = $this->{ChooseLSQMethodListBox}->GetText();
	my $FitTo  = $this->{ChooseFitToListBox}->GetText();

print "Method: $Method\n";
print "Fit to: $FitTo\n";
print "nMaxIter: $ini->{nMaxIter}\n";

	my $el        = $this->{Ellipsometry};
	my $pObsE     = $el->GetData('.*eV.*', '.*E.*');
	my $pObsPsi   = $el->GetData('Psi');
	my $pObsDelta = $el->GetData('Delta');
	my $pObsEps1  = $el->GetData('e1');
	my $pObsEps2  = $el->GetData('e2');

	$optimize->SetnS2Calculation(0);
#	$this->{nS2} = 0;
	my ($OptVars, $MinVal) = $optimize->Optimize(
				$Method, undef, undef, undef,
				$ini->{EPS}, $ini->{nMaxIter}, $ini->{iPrintLevel},
				sub { $this->CalS2($FitTo, $pObsE, $pObsPsi, $pObsDelta, $pObsEps1, $pObsEps2, @_); },
				undef,
				sub { Optimize::BuildDifferentialMatrixes(@_); },
				);
	print "\nOptimized at:\n";
	$optimize->PrintParameters(1);

	$optimize->RecoverParameters($OptVars);
	$this->SetS2($MinVal);

	$this->UpdateParameters();
}

sub CalS2
{
	my ($this, $FitTo, $pObsE, $pObsPsi, $pObsDelta, $pObsEps1, $pObsEps2, $pVars, $iPrintLevel) = @_;
#print "pVars=", join(',', @$pVars);

	my $optimize = $this->{Optimize};
	my $ini      = $this->{ini};

	$optimize->RecoverParameters($pVars);
#	$this->UpdateParameters();
	$this->BuildLayerModel(0, 0);
	my ($pE, $pe1, $pe2, $pPsi, $pDelta, $pIs, $pIc, $S2)
			= $this->CalEpsPsiDelta($this->{Layers}, $pObsE, $pObsPsi, $pObsDelta, $pObsEps1, $pObsEps2, $FitTo);

	$optimize->IncrementnS2();
	my $nS2         = $optimize->nS2Calculation();
	my $nS2Interval = $ini->{nSaveSpectraInterval};
	print "S2[$nS2] = $S2 / ";
	$S2 += $optimize->CalPenalty(1.0e10, $pVars, 1);
	print "$S2\n";
	$optimize->PrintParameters(1, $pVars, $S2);

	if($nS2Interval > 0 and $nS2 % $nS2Interval == 0) {
		$this->Recalc();
#		$this->CreateGraphFrame();
		$this->AssignGraphData(0);
		$this->Draw();
	}
	$this->mw()->update();

	return $S2;
}

sub CalEpsPsiDelta
{
	my ($this, $Layers, $pObsE, $pObsPsi, $pObsDelta, $pObsEps1, $pObsEps2, $FitTo) = @_;
	my $ini = $this->{ini};
	my $el  = $this->{Ellipsometry};

	my $Angle = $ini->{Angle};
	my $nData = @$pObsE;
	my (@E, @e1, @e2, @Psi, @Delta, @Is, @Ic);
	my $S2 = 0.0;
	my $c = 0;
	for(my $i = 0 ; $i < $nData ; $i++) {
		next if($ini->{nSkipData} > 0 and $i % $ini->{nSkipData} != 0);
		my $E  = $pObsE->[$i];
		next if($E < $ini->{FitEmin} or $ini->{FitEmax} < $E);

		my ($Psi, $Delta) = $Layers->CalPsiDelta($E);
		my ($e1c, $e2c)   = $el->PsiDeltaToEps($Psi, $Delta, $Angle);
		$E[$c]     = $E;
		$e1[$c]    = $e1c;
		$e2[$c]    = $e2c;
		$Psi[$c]   = $Psi;
		$Delta[$c] = $Delta;
#print "E=$E, e=($e1c,$e2c), Psi=($Psi,$Delta)\n";

		if(!defined $pObsPsi) {
			$c++;
			next;
		}

#my $pIs = $el->GetData('Is');
#my $pIc = $el->GetData('Ic');
		if($FitTo eq 'Eps') {
			$S2 += ($pObsEps1->[$i] - $e1c)**2 + ($pObsEps2->[$i] - $e2c)**2;
		}
		elsif($FitTo eq 'PsiDelta') {
			my $dPsi   = $pObsPsi->[$i]   - $Psi;
			my $dDelta = $pObsDelta->[$i] - $Delta;
			$dDelta -= 360.0 if($dDelta >   180.0);
			$dDelta += 360.0 if($dDelta <= -180.0);
			$S2 += $dPsi*$dPsi + $dDelta*$dDelta;
		}
		elsif($FitTo eq 'IsIcII') {
			my ($Iso, $Ico)    = $el->PsiDeltaToIsIcConfigrationII($pObsPsi->[$i], $pObsDelta->[$i]);
			($Is[$c], $Ic[$c]) = $el->PsiDeltaToIsIcConfigrationII($Psi, $Delta);
#print "Is=($Iso,$pIs->[$i],$Is[$c])\n";
#print "Ic=($Ico,$pIc->[$i],$Ic[$c])\n";
			my $ds = $Iso - $Is[$c];
			my $dc = $Ico - $Ic[$c];
			$S2 += $ds*$ds + $dc*$dc;
		}
		elsif($FitTo eq 'IsIcIII') {
			my ($Iso, $Ico)    = $el->PsiDeltaToIsIcConfigrationIII($pObsPsi->[$i], $pObsDelta->[$i]);
			($Is[$c], $Ic[$c]) = $el->PsiDeltaToIsIcConfigrationIII($Psi, -$Delta);
			my $ds = $Iso - $Is[$c];
			my $dc = $Ico - $Ic[$c];
			$S2 += $ds*$ds + $dc*$dc;
		}
		else {
			print "Error: Invalid Fitting Target [$FitTo].\n";
			exit;
		}
		$c++;
	}
	$S2 = sqrt($S2 / $c);
	return (\@E, \@e1, \@e2, \@Psi, \@Delta, \@Is, \@Ic, $S2);
}

sub CreateGraphFrame
{
	my ($this, $canvas, $TargetData) = @_;
	$canvas = $this->Canvas();
	my $App = $this->App();
	my $font = $App->{'GraphFrameFont'};
	my @font = split(/,/, $font) if($font);
	my $w = $canvas->width();
	my $h = $canvas->height();

	my $GraphFrameArray = $this->{'GraphFrameArray'} = new GraphFrameArray($this->mw());

	$GraphFrameArray->SetCanvasSize($w, $h);

	$GraphFrameArray->AddGraphFrame();
	my $GraphFrame0  = $GraphFrameArray->GetGraphFrame(0);
	my $FramePosStr0 = $App->{"GraphFrame0Position"};
	my $XScale0      = $GraphFrame0->GetXScale(0);
	my $YScale0      = $GraphFrame0->GetYScale(0);
	$GraphFrame0->SetPositionByStr($FramePosStr0);

	$XScale0->SetScaleStringVisible(1);
	$XScale0->SetCaptionVisible(1);

	$GraphFrame0->SetViewRange(0, 0, 1, 1);
}

sub AssignGraphData
{
	my ($this, $ResetViewRange) = @_;
	$ResetViewRange = 1 if(!defined $ResetViewRange);

	my $GraphFrameArray = $this->GetGraphFrameArray();
	my $GraphFrame0  = $GraphFrameArray->GetGraphFrame(0);
	$GraphFrame0->ClearAllData();

	my $XLabel  = $this->{"ChooseXListBox"}->GetText();
	$XLabel = 'X' if(!$XLabel);
	my $Y1Label = $this->{"ChooseY1ListBox"}->GetText();
	$Y1Label = 'Y1' if(!$Y1Label);
	my $Y2Label = $this->{"ChooseY2ListBox"}->GetText();
	$Y2Label = 'Y2' if(!$Y2Label);
	$GraphFrame0->SetXCaption($XLabel);
	$GraphFrame0->SetYCaption("$Y1Label,$Y2Label");

	my $pX    = $this->{Ellipsometry}->GetData($XLabel, '.*E.*', '.*eV.*');
	my $pY1   = $this->{Ellipsometry}->GetData($Y1Label);
	my $pY2   = $this->{Ellipsometry}->GetData($Y2Label);
	my $nData = $this->{Ellipsometry}->nData();
	if($pX) {
		$GraphFrame0->AddGraphData($pX, $pY1,
				2, "black", "", 6, "red", 0, "red", "XAutoSkip", "Energy", "${Y1Label}(obs)") if($pY1);
		$GraphFrame0->AddGraphData($pX, $pY2,
				2, "red",   "", 6, "red", 0, "red", "XAutoSkip", "Energy", "${Y2Label}(obs)") if($pY2);
	}

	my $pCalE = $this->{pEArray};
	my $pCalY1 = $this->{"p${Y1Label}Array"};
	my $pCalY2 = $this->{"p${Y2Label}Array"};
	if($pCalE) {
		$GraphFrame0->AddGraphData($pCalE, $pCalY1,
				0, "black", "circle", 3, "", 1, "black", "XAutoSkip", "Energy", "${Y1Label}(cal)") if($pCalY1);
#				1, "black", "", 6, "red", 0, "red", "XAutoSkip", "Energy", "${Y1Label}(cal)") if($pCalY1);
		$GraphFrame0->AddGraphData($pCalE, $pCalY2,
				0, "red",   "circle", 3, "", 1, "red", "XAutoSkip", "Energy", "${Y2Label}(cal)") if($pCalY2);
#				1, "red",   "", 6, "red", 0, "red", "XAutoSkip", "Energy", "${Y2Label}(cal)") if($pCalY2);
	}

	$GraphFrame0->SetYScalePlotType('x');
	if($ResetViewRange) {
		$GraphFrame0->CalMinMax();
		$GraphFrame0->AdjustViewRange(0.05, 0.05, 0.05, 0.05);
	}
}