@echo off

rem ======================================================
rem プログラムパスを設定
rem ======================================================
set pandoc_exe=g:\pandoc
set script_textbook=..\..\download\tkprog_textbook\ai\make_textbook5.py
set script_pandoc=..\..\download\tkprog_textbook\converter\pandoc.py

rem ======================================================
rem 入力ファイル情報を設定
rem ======================================================
rem 入力文字起こしファイルのファイル名から拡張子を除いた部分
set transcribe_prefix=チュートリアル-結晶学03-逆格子と共変・反変テンソル
rem 入力スライドファイルのMarkdownファイル名
set slide_path=チュートリアル-結晶学03-逆格子と共変・反変テンソル.md

rem ======================================================
rem role情報、出力言語を設定
rem ======================================================
set field=材料科学
set role=日本の大学院教授
set lang=ja


rem ======================================================
rem 入力ファイル情報から、必要なファイル名を作成 (変更不要)
rem ======================================================
rem 入力文字起こしファイルのファイル名
set transcribe_path=%transcribe_prefix%.txt
rem 出力textbookファイルのファイル名
set output_text_path=%transcribe_prefix%_textbook.md
rem 出力slideファイルのファイル名
set output_slide_path=%transcribe_prefix%_slide.md


rem ======================================================
rem 生成AIで教科書とスライドのMarkdownファイルを作成
rem ======================================================
set cmd=python %script_textbook% -i "%transcribe_path%" -im  "%slide_path%" -t "%output_text_path%" -s "%output_slide_path%" -a gemini --lang %lang% --field %field% --role %role%

echo.
echo Run [%cmd%]

:%cmd%


rem ======================================================
rem 教科書Markdownファイルが作成されていたら、MS-Wordファイルに変換
rem ======================================================
if not exist "%output_text_path%" (
    echo エラー: ファイル %output_text_path% の作成に失敗しました
    exit /b 1
)
rem templateを使う場合
set cmd_docx=python %script_pandoc% --pandoc_path %pandoc_exe% --convert docx --template template_text.docx --infile %output_text_path%
rem templateを使わない場合
:set cmd_docx=python %script_pandoc% --convert docx --infile %output_text_path%

echo.
echo Run [%cmd_docx%]
%cmd_docx%


rem ======================================================
rem スライドMarkdownファイルが作成されていたら、PowerPointファイルに変換
rem ======================================================
if not exist "%output_slide_path%" (
    echo エラー: ファイル %output_slide_path% の作成に失敗しました
    exit /b 1
)
rem templateを使う場合
set cmd_pptx=python %script_pandoc% --pandoc_path %pandoc_exe% --convert pptx --template template_slide.pptx --infile %output_slide_path%
rem templateを使わない場合
:set cmd_pptx=python %script_pandoc% --convert pptx --infile %output_slide_path%

echo.
echo Run [%cmd_pptx%]
%cmd_pptx%


:END